@ECHO OFF
REM Limpio ventana
COLOR 3F
CLS

REM Variables generales
SET directorio=%CD%\TempEscaner
SET servidorFTP=10.1.10.9
SET fecha=%DATE:~6,4%-%DATE:~3,2%-%DATE:~0,2%

:menu
REM Muestro menu principal
ECHO Menu principal
ECHO ===============
ECHO 1. Radicados
ECHO 2. Guias
ECHO ===============
SET /p opcionMenu=Ingrese la opcion deseada: 

IF "%opcionMenu%"=="1" (
	SET titulo=Escaneo de radicados
	GOTO inicio
) ELSE IF "%opcionMenu%"=="2" (
	SET titulo=Escaneo de guias
	GOTO inicio
) ELSE (
	CLS
	ECHO Opcion incorrecta reintente
	GOTO menu
)

GOTO:eof

:inicio
REM Verifico existencia de directorio
IF NOT EXIST %directorio% (MD %directorio%)

REM Borro archivos anteriores
DEL %directorio%\*.pdf /Q
DEL %directorio%\*.txt /Q
CLS

REM Muestro titulo de programa
ECHO %titulo%
ECHO ======================

REM Pido radicado
SET /p radicado=Ingrese el radicado: 

REM Edito el nombre de archivo y la url
SET nombreArchivo=%radicado%_%fecha%_%RANDOM%
SET archivoObservaciones=%nombreArchivo%.txt
SET archivo=%nombreArchivo%.pdf

IF "%opcionMenu%"=="1" (
	SET url=http://%servidorFTP%/pqrs/upload_files/radicados/%radicado%/%nombreArchivo%
	GOTO escaneo
) ELSE IF "%opcionMenu%"=="2" (
	SET url=http://%servidorFTP%/pqrs/upload_files/guias/%radicado%/%nombreArchivo%
	GOTO guias
)

GOTO:eof

:escaneo
REM Escaneo hojas
ECHO Escaneando...
naps2\NAPS2.Console.exe -o "%directorio%\archivoTemporal.pdf" -p "pqrs"
REM COPY archivo.pdf %directorio%\archivoTemporal.pdf
IF EXIST %directorio%\%archivo% (GOTO combinacion) ELSE (MOVE %directorio%\archivoTemporal.pdf %directorio%\%archivo%)

SET /p opcionEscaneo=Desea escanear otra pagina? (S/N): 

IF %opcionEscaneo% == s (GOTO escaneo) 
IF %opcionEscaneo% == S (GOTO escaneo)
IF %opcionEscaneo% == n (GOTO fin) 
IF %opcionEscaneo% == N (GOTO fin)
GOTO:eof

:combinacion
pdftk\pdftk.exe A=%directorio%\%archivo% B=%directorio%\archivoTemporal.pdf output "%directorio%\archivoTemporal2.pdf"
DEL %directorio%\archivoTemporal.pdf /Q
DEL %directorio%\%archivo% /Q
MOVE %directorio%\archivoTemporal2.pdf %directorio%\%archivo%

SET /p opcionEscaneo=Desea escanear otra pagina? (S/N): 

IF %opcionEscaneo% == s (GOTO escaneo) 
IF %opcionEscaneo% == S (GOTO escaneo)
IF %opcionEscaneo% == n (GOTO fin) 
IF %opcionEscaneo% == N (GOTO fin)
GOTO:eof

:fin
REM Copiando archivo al servidor
FTP -s:ftp.txt %servidorFTP%

ECHO Visualizo el archivo
START %url%
GOTO inicio
GOTO:eof

:guias
SET /p observaciones=Ingrese observaciones de guia: 
ECHO %observaciones% > %directorio%\%archivoObservaciones%

REM Inicio ciclo de escaneo 
GOTO escaneo
GOTO:eof